home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / A-Monthly Disks / (c)abc.d64 / reu dissolvshow (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  2KB  |  92 lines
  1. 0 REM *******************************
  2. 1 REM *** 1750/1764 REU SLIDESHOW ***
  3. 2 REM *** DESIGNED AND WRITTEN BY ***
  4. 3 REM *** - JAMES HASTINGS-TREW - ***
  5. 4 REM ***      JULY 19,1988       ***
  6. 5 REM ***  AT THE SUGGESTION OF   ***
  7. 6 REM ***    JUDITH M. BALDWIN    ***
  8. 7 REM ***    OF THE E.C.C.U.G.    ***
  9. 8 REM *******************************
  10. 9 :
  11. 10 IF A=1THEN39
  12. 11 IF X=0THENX=1:LOAD"FASTBOOT",8,1
  13. 12 IFX=1THENX=2:SYS51200:LOAD"DISSOLVE",8,1
  14. 13 IFX=2THEN19
  15. 14 SYS34592:POKE53281,PEEK(34576)
  16. 15 SYS34592+3
  17. 16 RETURN
  18. 17 POKE53281,0:SYS34592+6:SYS34592+9
  19. 18 RETURN
  20. 19 POKE53280,0:POKE53281,0
  21. 20 IFA=1GOTO40
  22. 21 PRINT"[147][158]     1750/1764 [203]OALAPAINT [211]LIDE [211]HOW    "
  23. 22 PRINT"[159] [196]O YOU HAVE A [210]AM [197]XPANSION [213]NIT        INSTALLED? <Y/N>"
  24. 23 RU=0:POKE198,0:WAIT198,1:GETA$:IFA$="Y"THENRU=1:GOSUB87:GOTO25
  25. 24 IFA$<>"N"THEN23
  26. 25 INPUT" [197]NTER TIME (SEC.) FOR EACH PICTURE";TM:IFTM<0ORTM>59THEN25
  27. 26 TM=TM*60
  28. 27 PRINT:PRINT" [201]NSERT DATA DISK IN DRIVE <RETURN>"
  29. 28 GETA$:IFA$=""THEN28
  30. 29 DIMF$(16):POKE198,0
  31. 30 GOSUB 46
  32. 31 IFNN=0THENPRINT"[147]SORRY, NO KOALA PICTURES ON THIS DISK":END
  33. 32 PRINT"PRESS ANY KEY DURING THE SLIDE SHOW TO  STOP"
  34. 33 GS=0
  35. 34 IFGS=NN THEN RO=1:GOTO33
  36. 35 G$=LEFT$(F$(GS),15)
  37. 36 FC=PEEK(53281):CC=PEEK(646)
  38. 37 IF RU=1 AND RO=1 THEN GOSUB 75:GOTO 40
  39. 38 A=1:LOADG$,8,1
  40. 39 IF RU=1 AND RO=0 THEN GOSUB 63
  41. 40 GOSUB17:GOSUB14:TI$="000000"
  42. 41 IFTI<TMTHEN41
  43. 42 GS=GS+1:GETA$:IFA$=""THEN34
  44. 43 GOSUB17
  45. 44 PRINT"[147]DONE!":POKE53281,0
  46. 45 END
  47. 46 REM DIRECTORY READ
  48. 47 PRINT"[147][158]LIST OF ALL KOALA PICTURES ON THIS DISK"
  49. 48 OPEN15,8,15:OPEN5,8,5,"#":T=18:S=1:NN=0:Z$=CHR$(0)
  50. 49 PRINT#15,"U1:"5;0;T;S:PRINT#15,"B-P:"5;0:GET#5,T$,S$
  51. 50 T=ASC(T$+Z$):S=ASC(S$+Z$):BP=5:FL=1
  52. 51 PRINT#15,"B-P:"5;BP:GET#5,A$:IFA$="[129]"THENGOSUB56
  53. 52 BP=BP+32:FL=FL+1:IFFL<>9THEN51
  54. 53 IFT=18THEN49
  55. 54 CLOSE5:CLOSE15:T$="":S$="":A$="":N=FRE(0)
  56. 55 RETURN
  57. 56 REM LISTER
  58. 57 PRINT"[193][146]";
  59. 58 FORX=1TO15
  60. 59 F$(NN)=F$(NN)+A$:GET#5,A$:PRINTA$;
  61. 60 NEXT
  62. 61 N=FRE(0):NN=NN+1:PRINT
  63. 62 RETURN
  64. 63 REM LOAD PIC INTO REU
  65. 64 AD=GS*10010:AB=INT(AD/65536):AD=AD-(65536*AB):AH=INT(AD/256)
  66. 65 AL=AD-(AH*256)
  67. 66 POKE57096,39:REM PIC LEN HI-BYTE
  68. 67 POKE57095,17:REM PIC LEN LO-BYTE
  69. 68 POKE57094,AB:REM REU BANK
  70. 69 POKE57093,AH:REM REU ADDR HI-BYTE
  71. 70 POKE57092,AL:REM REU ADDR LO-BYTE
  72. 71 POKE57091,96:REM PIC ADDR HI-BYTE
  73. 72 POKE57090,00:REM PIC ADDR LO-BYTE
  74. 73 POKE57089,144:REM DO IT!
  75. 74 RETURN
  76. 75 REM LOAD PIC FROM REU
  77. 76 AD=GS*10010:AB=INT(AD/65536):AD=AD-(65536*AB):AH=INT(AD/256)
  78. 77 AL=AD-(AH*256)
  79. 78 POKE57096,39:REM PIC LEN HI-BYTE
  80. 79 POKE57095,17:REM PIC LEN LO-BYTE
  81. 80 POKE57094,AB:REM REU BANK
  82. 81 POKE57093,AH:REM REU ADDR HI-BYTE
  83. 82 POKE57092,AL:REM REU ADDR LO-BYTE
  84. 83 POKE57091,96:REM PIC ADDR HI-BYTE
  85. 84 POKE57090,00:REM PIC ADDR LO-BYTE
  86. 85 POKE57089,145:REM DO IT!
  87. 86 RETURN
  88. 87 REM INITIALIZE REU
  89. 88 POKE 57098,0:REM ADDR CONTROL
  90. 89 POKE 57097,128:REM INTERRUPTS
  91. 90 RETURN
  92.